;Toggling 8 LEDs on PORTA using Freescale Student Project Board with HCS12 MCU Module  
;HCS12 MCU Modules come with USB-BDM and ready to be used with CodeWarrior IDE

;In HCS12 MCU Modules RAM address is from $1000-3FFF 
;We use RAM addresses starting at $1000 for scratch pad (variables) and $3FFF for Stack

;Notice the following facts about the Student Project Board
;a) the lower 4 bits of PA3-PA0 are connected to LEDs(LED1-LED4 on J10) permanently 
;b) they must be enabled by clearing bit P4 of PORTP. 
;c) MAKE SURE jumper for these LEDs is set. LED JUMPER is part of group of jumpers called UFEA right next to the Buzzer 
;d) We also need to connect 4 wires from LED5-LED8 (J10) to pins PA7-PA4 via J6 connector(pins 25,27,29,31)


;On HCS12 MCU Module itself,
;a)MAKE SURE ALL the jumpers for PORTB are removed.(SW3-1...SW3-4 and LED1-LED4) 
;b)The 8 Jumpers (SW3-1...SW3-4 and LED1-LED4) on HCS12 MCU module connect the PORTB to SW and LEDs of the Module itself.  
;c)The PORTB can be either used by the HCS12 MCU Module itself or the Project Board, but not both of them at the same 
;e) WE USE THIS LAB EXTENSIVELY IN FUTURE LABs.SO KEEP THE LEDs CONNECTED TO PORTA

;See Chapter 4 of Mazidi & Causey HCS12 textbook
 
;In CodeWarrior, make sure you are in TBDML Mode before downloading 
;Press F7 (to Make), then F5(Debug) to downLOAD,and F5 once more to start the program execution
   
        ABSENTRY Entry        ; for absolute assembly: mark this as application entry point
    
; Include derivative-specific definitions 
		INCLUDE 'mc9s12dt256.inc'     ;CPU used by Axiom board
 
 
;----------------------USE $1000-$2FFF for Scratch Pad 
R1      EQU     $1001
R2      EQU     $1002
R3      EQU     $1003

;code section
        ORG   $4000     ;Flash ROM address 
Entry:
	      LDS     #$4000    ;Stack
        LDAA    #$FF
        STAA    DDRA	;Make PA7-PA0 as output
        BSET    DDRP, %00010000 ;the lower 4 bits of PA3-PA0 are connected to LEDs(LED1-LED4) permanently
        BCLR    PTP,  %00010000 ; and must be enabled by clearing bit P4 of PORTP
                                ;We need connect 4 wires from LED5-LED8 to pins PA4-PA7 via J6 connector 
          
;-------Toggling LEDs on PA7-PA0 of PORTA

BACK   LDAA #$55
    	 STAA PORTA		;Store A into PORTA
	     JSR DELAY
	     LDAA #$AA
	     STAA PORTA
	     JSR DELAY

	      BRA BACK    
  
;----------DELAY
DELAY

        PSHA		;Save Reg A on Stack
        LDAA    #10		;Change this value to see  
        STAA    R3		;how fast LEDs Toggle
;--10 msec delay. The HCS12 MCU Module works with XTAL=4MHz 
;Freq. for Instruction Clock Cycle is 2MHz (1/2 of 4MHz). 
;(1/2MHz) x 10 Clk x10x200=10 msec. Overheads are excluded in this calculation.         
L3      LDAA    #10
        STAA    R2
L2      LDAA    #200
        STAA    R1
L1      NOP         ;1 Intruction Clk Cycle
        NOP         ;1
        NOP         ;1
        DEC     R1  ;4
        BNE     L1  ;3
        DEC     R2  ;Total Instr.Clk=10
        BNE     L2
        DEC     R3
        BNE     L3
;--------------        
        PULA			;Restore Reg A
        RTS
;-------------------

            
;**************************************************************
;*                 Interrupt Vectors                          *
;**************************************************************
            ORG   $FFFE
            DC.W  Entry     ;Reset Vector. CPU wakes here and it is sent to start of the code at $4000